home *** CD-ROM | disk | FTP | other *** search
/ Aminet 21 / Aminet 21 (1997)(GTI - Schatztruhe)[!][Oct 1997].iso / Aminet / dev / c / IFFConverter.lha / SavePicture.a.bak < prev    next >
Encoding:
Text File  |  1997-01-08  |  17.0 KB  |  710 lines
  1. **
  2. **     $VER: SavePicture.a V1.00 (06-12-95)
  3. **
  4. **     Author:  Gerben Venekamp
  5. **     Updates: 06-12-95  Versin 1.00     Initial Module
  6. **
  7. **  SavePicture.a save a screen buffer to a file. This can be done
  8. **  in a number of ways. Possible types of saving: Interleave, RAW
  9. **  Copper and Font8.
  10. **
  11.  
  12.         include    graphics/view.i
  13.         
  14.         
  15. ExtensionSize    equ    6    // Changes should be made to IFFConverter.h too
  16.  
  17.         
  18.         XDEF    _SaveInterleave
  19.         XDEF    _SaveRaw
  20.         XDEF    _SaveCopperAGA
  21.         XDEF    _SaveCopperECS
  22.         XDEF    _SaveCopper32bit
  23.         XDEF    _SaveCopper4bit
  24.         XDEF    _SaveFont8
  25.         
  26.         XREF    _DOSBase
  27.         XREF    _PicDepth
  28.         
  29.         include    exec/types.i
  30.         include    exec/strings.i
  31.         include    dos/dos.i
  32.         include    graphics/gfx.i
  33.  
  34.         include    dos_lib.i
  35.         
  36.         include    Gadgets_enum.i
  37.         
  38.  
  39.         STRUCTURE Save_Buffer_struct,0
  40.            APTR   Buffer
  41.            ULONG  BufferSize
  42.            ULONG  BufferLeft
  43.            BPTR   FileHeader
  44.  
  45.  
  46. * Macro for adding text to an ASCII file
  47.  
  48. AddText        MACRO
  49.         lea    (\1,PC),a5    Set start of text.
  50.         IFLT    (\2-1<<7)    See if text fits in a 'moveq'.
  51.         moveq    #\2,d7        Set text size.
  52.         ELSE            Text size needs to be a longword.
  53.         move.l    #\2,d7        Set text size.
  54.         ENDC
  55.         
  56.         jsr    WriteBuffer    Write text to a buffer.
  57.         ENDM
  58.         
  59. *--------------------------------------------------------------------
  60. *
  61. *  To call a library function use LIBCALL. If A6 is correct, just
  62. *  use LIBCALL with the functionname only. If A6 isn't correct,
  63. *  than use LIBCALL with the functionname AND the library offset.
  64. *
  65. *--------------------------------------------------------------------
  66.  
  67. LIBCALL        MACRO
  68.         IFGT    NARG-2        More Then Two Arguments?
  69.         FAIL            Too many Arguments!!!
  70.         ENDC
  71.         IFEQ    NARG-2        Two Arguments exactly.
  72.         move.l    (_\2),a6
  73.         ENDC
  74.         jsr    (_LVO\1,a6)
  75.         ENDM
  76.         
  77.  
  78. *-------------------------------------------------------------------------
  79. *
  80. *  SaveInterleave(BitMap, BitPlanePtrs, IFFClip, SaveBuffer)
  81. *                 A0      A1            A2       A3
  82. *
  83. *     Save a screen buffer to a file. If a 'SaveBuffer' exists, use it to
  84. *     store the data temporary. If it doesn't, save the screen buffer
  85. *     directly to 'SaveName'. 'SaveName' should be a valid name, because
  86. *     no checking is done to see if 'SaveName' exists or not.
  87. *
  88. *  pre:  A0 - Pointer to the BitMap structure of the screen to be saved.
  89. *        A1 - Pointer to an allocted block of memory. This will be filled
  90. *             with the appropiate pointer values to the bitmaps. The size
  91. *             of this block should be at least: bm_Depth × 4 bytes.
  92. *        A2 - Pointer to a structure containing all the necessary clipping
  93. *             values.
  94. *        A3 - Pointer to a buffer structure.
  95. *  post: None.
  96. * 
  97. *-------------------------------------------------------------------------
  98.  
  99. _SaveInterleave
  100.         SECTION    SaveInterleave,code
  101.  
  102.         movem.l    a4-5,-(SP)
  103.         
  104.         move.l    a1,a4
  105.         lea    (bm_Planes,a0),a5        Copy the bitplane pointers, because
  106.         move.w    (bm_Depth,a0),d0        we will touch them.
  107.         subq.w    #1,d0
  108. CopyBitplanePtr
  109.         move.l    (a5)+,(a4)+
  110.         dbf    d0,CopyBitplanePtr
  111.         
  112.         movem.l    (SP)+,a4-5
  113.         
  114.         rts
  115.  
  116.  
  117.         SECTION    SaveRaw,code
  118. _SaveRaw
  119.         movem.l    a4-5,-(SP)
  120.         
  121.         move.l    a1,a4
  122.         lea    (bm_Planes,a0),a5        Copy the bitplane pointers, because
  123.         move.w    (bm_Depth,a0),d0        we will touch them.
  124.         subq.w    #1,d0
  125. CpBitplanePtr
  126.         move.l    (a5)+,(a4)+
  127.         dbf    d0,CpBitplanePtr
  128.         
  129.         movem.l    (SP)+,a4-5
  130.  
  131.         rts
  132.  
  133.  
  134. *-------------------------------------------------------------------------
  135. *
  136. *  SaveCopper(ColourMap, SaveBuffer )
  137. *             A2         A3
  138. *
  139. *     Save a colourmap to a file. The name of the file can be found in
  140. *     'SaveBuffer'. Since there are currently two distingt chipsets,
  141. *     there are different ways to build a colourmap. One for the ECS and
  142. *     one for AGA. Secondly a colourmap colould be directly implemented
  143. *     as a CopperList, or just the colour data itself and the programmer
  144. *     takes care of the building the CopperList himself. Anyway, this
  145. *     leaves us with four possible way of saving a colourmap. We could
  146. *     ask the user to specify how to save the colourmap or take awy the
  147. *     burden and save them all at once. Since a colourmap does not take
  148. *     up much space, the later methos is prefered. This way, the user
  149. *     will always have the right colourmap.
  150. *     The four ways a colourmap is saved are:
  151. *        1 - AGA             extension will be .AGA
  152. *        2 - ECS             extension will be .ECS
  153. *        3 - 32 bit colours  extension will be .32bit
  154. *        4 -  4 bit colours  extension will be .4bit
  155. *
  156. *  pre:  A2 - Pointer to the ColourMap of the screen to be saved.
  157. *             The structure is the same as for 'LoadRGB32' colourmaps.
  158. *        A3 - Pointer to a buffer structure.
  159. *        A4 - SAS C Stack offset.
  160. *  post: None.
  161. * 
  162. *-------------------------------------------------------------------------
  163.         SECTION    SaveCopper
  164.         
  165. * Code can be found after data!
  166.  
  167.         
  168.         ENUM
  169.           EITEM    dctype_Word
  170.           EITEM    dctype_Long
  171.  
  172. AGAHeader    dc.b    '**',LF
  173.         dc.b    '**     $VER: AGA CopperList',LF
  174.         dc.b    '**',LF
  175.         dc.b    '**     Author: Gerben Venekamp',LF
  176.         dc.b    '**',LF
  177.         dc.b    '**  This is an AGA CopperList made with the IFFConverter.',LF
  178.         dc.b    '**  Just insert this at the appropiate place inside your',LF
  179.         dc.b    '**  Copper List.',LF
  180.         dc.b    '**',LF,LF
  181. ASCII_OrMask    dc.b    'BPLCON3OrMask'
  182. ASCII_OrMaskSize    equ    *-ASCII_OrMask
  183.         dc.b    '    equ    $'
  184. BPLCON3OrMask    dc.b    '0000'
  185.         dc.b    LF
  186. AGAHeaderSize    equ    *-AGAHeader
  187.         
  188. ECSHeader    dc.b    '**',LF
  189.         dc.b    '**     $VER: ECS CopperList',LF
  190.         dc.b    '**',LF
  191.         dc.b    '**     Author: Gerben Venekamp',LF
  192.         dc.b    '**',LF
  193.         dc.b    '**  This is an ECS CopperList made with the IFFConverter.',LF
  194.         dc.b    '**  Just insert this at the appropiate place inside your',LF
  195.         dc.b    '**  Copper List.',LF
  196.         dc.b    '**',LF
  197. ECSHeaderSize    equ    *-ECSHeader
  198.  
  199. bit32Header    dc.b    '**',LF
  200.         dc.b    '**     $VER: 32 bit Colour map',LF
  201.         dc.b    '**',LF
  202.         dc.b    '**     Author: Gerben Venekamp',LF
  203.         dc.b    '**',LF
  204.         dc.b    '**  This is an 32 bit colourmap made with the IFFConverter.',LF
  205.         dc.b    '**  See autodocs/graphics/LoadRGB32 for the structure explaination.',LF
  206.         dc.b    '**  You could pass it on to LoadRGB32.',LF
  207.         dc.b    '**',LF
  208. bit32HeaderSize    equ    *-bit32Header
  209.  
  210. bit4Header    dc.b    '**',LF
  211.         dc.b    '**     $VER: 4 bit Colour map',LF
  212.         dc.b    '**',LF
  213.         dc.b    '**     Author: Gerben Venekamp',LF
  214.         dc.b    '**',LF
  215.         dc.b    '**  This is an 4 bit colourmap made with the IFFConverter.',LF
  216.         dc.b    '**  Each word represents a total RGB colour. Each colour compentent',LF
  217.         dc.b    '**  is a 4 bit value.',LF
  218.         dc.b    '**',LF
  219. bit4HeaderSize    equ    *-bit4Header
  220.  
  221.  
  222. ASCII_TAB    dc.b    '    '
  223. TABSize        equ    *-ASCII_TAB
  224. ASCII_LF        dc.b    LF
  225. LFSize        equ    *-ASCII_LF
  226. Line_dcw        dc.b    'dc.w'
  227. Line_dcw_Length    equ    *-Line_dcw
  228. Line_dcl        dc.b    'dc.l'
  229. Line_dcl_Length    equ    *-Line_dcl
  230. ColourPart    dc.b    'color+'
  231. ColourPartLength    equ    *-ColourPart
  232. ColourOffset    dc.b    '00'
  233. ColourOffsetSize    equ    *-ColourOffset
  234. ColourValue    dc.b    '000'
  235. ColourValueSize    equ    *-ColourValue
  236. ColourBank    dc.b    'bplcon3,$'
  237. ColourBankSize    equ    *-ColourBank
  238. BPLCON3Value    dc.b    '0000'
  239. BPLCON3ValueSize    equ    *-BPLCON3Value
  240. ColourValue24    dc.b    '000000'
  241. ColourValue24Size    equ    *-ColourValue24
  242. Comma        dc.b    ','
  243. CommaLength    equ    *-Comma
  244. CommaStr        dc.b    ',$'
  245. CommaStrLength    equ    *-CommaStr
  246. ASCII_Str    dc.b    '$'
  247. ASCII_StrSize    equ    *-ASCII_Str
  248. ASCII_Or        dc.b    '|'
  249. ASCII_OrSize    equ    *-ASCII_Or
  250.         CNOP    0,2
  251.  
  252. ColourCount    dc.w    0
  253. BPLCON3Extra    dc.w    0
  254.  
  255. bplcon3_LOCTbit    equ    9
  256.  
  257. **
  258. **  Here's where the fun begins, pure code.
  259. **
  260. _SaveCopperAGA
  261.         movem.l    d2-3/d5-7/a5-6,-(SP)    Store affected non scratch registers
  262.         
  263.         clr.w    (BPLCON3Extra)
  264.         AddText    AGAHeader,AGAHeaderSize
  265.         move.l    a2,-(SP)
  266. DoLowNibles
  267.         move.l    (a2)+,d6
  268.         swap    d6
  269.         move.w    d6,(ColourCount)
  270.         subq.w    #1,d6
  271.         move.w    d6,d5            For Later use
  272.         lsr.w    #5,d6
  273.         bpl.s    MakeAGA
  274.         moveq    #0,d6
  275. MakeAGA
  276.         jsr    AddColourBank
  277.         and.w    #$1f,d5
  278. MakeAGA.1
  279.         move.w    #dctype_Word,d0
  280.         bsr    AddStartLine
  281.         
  282.         cmp.w    (_NumberOfItems1),d5
  283.         blt.s    CorrectItems
  284.         move.w    (_NumberOfItems1),d4
  285.         subq.w    #1,d4
  286.         bra.s    RightItems
  287. CorrectItems        
  288.         move.w    d5,d4
  289. RightItems
  290.         sub.w    d4,d5
  291. MakeAGA.2
  292.         lea    (ColourOffset,PC),a0
  293.         move.w    (ColourCount),d0
  294.         subq.w    #1,d0
  295.         sub.w    d5,d0
  296.         sub.w    d4,d0
  297.         add.w    d0,d0
  298.         and.w    #$3f,d0
  299.         moveq    #ColourOffsetSize,d1
  300.         jsr    MakeDecimal
  301.  
  302.         cmp.w    #1<<bplcon3_LOCTbit,(BPLCON3Extra)
  303.         bne.s    BPLCON3_LowNible
  304.         
  305.         move.l    (a2)+,d0            Get Red component
  306.         and.l    #$f0000000,d0
  307.         moveq    #20,d2
  308.         lsr.w    d2,d0            Make R
  309.         move.l    (a2)+,d1            Get Green component
  310.         and.l    #$f0000000,d1
  311.         moveq    #24,d2
  312.         lsr.w    d2,d1
  313.         or.w    d1,d0            Make RG
  314.         move.l    (a2)+,d1            Get Blue component
  315.         and.l    #$f0000000,d1
  316.         moveq    #28,d2
  317.         lsr.l    d2,d1
  318.         or.w    d1,d0            Make RGB
  319.         bra.s    GotColourComponent
  320.  
  321. BPLCON3_LowNible
  322. ;  If not High Nibke that it must be Low Nible
  323.         move.l    (a2)+,d0            Get Red component
  324.         and.l    #$0f000000,d0
  325.         swap    d0            Make R
  326.         move.l    (a2)+,d1            Get Green component
  327.         and.l    #$0f000000,d1
  328.         moveq    #20,d2
  329.         lsr.l    d2,d1
  330.         or.w    d1,d0            Make RG
  331.         move.l    (a2)+,d1            Get Blue component
  332.         and.l    #$0f000000,d1
  333.         moveq    #24,d2
  334.         lsr.l    d2,d1
  335.         or.w    d1,d0            Make RGB
  336.         
  337. GotColourComponent        
  338.         moveq    #ColourValueSize,d1
  339.         lea    (ColourValue,PC),a0
  340.         jsr    MakeHex
  341.         
  342.         AddText    ColourPart,ColourPartLength
  343.         AddText    ColourOffset,ColourOffsetSize
  344.         AddText    CommaStr,CommaStrLength
  345.         AddText    ColourValue,ColourValueSize
  346.         tst.w    d4
  347.         beq.s    AGASkipComma
  348.         AddText    Comma,CommaLength
  349. AGASkipComma
  350.         
  351.         dbf    d4,MakeAGA.2
  352.         
  353.         dbf    d5,MakeAGA.1
  354.         
  355.         dbf    d6,MakeAGA
  356.  
  357. **
  358. **  Okay, a very big NOTE here!!!
  359. **  This piece of code works fine, but *any* extentions might cause
  360. **  problems!!!! BE AWARE OF THIS THREAD!!!!
  361. **
  362. **  What happens is, you need to write the same copperlist twice!
  363. **  This is due to the fact that you write the high nible of each
  364. **  of your 24 bit colour components first, than the low nibles.
  365. **  So, $123456 will be $135 followd by $246.
  366. **  A special bit takes care of the nibles. So using this nible it's
  367. **  an easy test to check when to stop. Any changes could upset this
  368. **  easy rule.
  369. **
  370.         move.l    (SP),A2
  371.         tst.w    (BPLCON3Extra,PC)
  372.         bne.s    EndOfAGA
  373.         or.w    #1<<bplcon3_LOCTbit,(BPLCON3Extra)
  374.         bra    DoLowNibles    
  375. EndOfAGA        
  376.         jsr    FlushBuffer
  377.         
  378.         addq.l    #4,SP
  379.         movem.l    (SP)+,d2-3/d5-7/a5-6    Restore affected non scratch registers
  380.         rts
  381.  
  382.  
  383. _SaveCopperECS
  384.         movem.l    d2-3/d6-7/a5-6,-(SP)    Store affected non scratch registers
  385.  
  386.         AddText    ECSHeader,ECSHeaderSize
  387.         
  388.         jsr    FlushBuffer
  389.         
  390.         movem.l    (SP)+,d2-3/d6-7/a5-6    Restore affected non scratch registers
  391.         rts
  392.  
  393.  
  394.  
  395. _SaveCopper32bit
  396.         movem.l    d2-3/d6-7/a5-6,-(SP)    Store affected non scratch registers
  397.  
  398.         AddText    bit32Header,bit32HeaderSize
  399.         
  400.         moveq    #dctype_Word,d0
  401.         jsr    AddStartLine
  402.         
  403.         move.l    (a2)+,d5
  404.         lea    (BPLCON3Value,PC),a0
  405.         move.w    d5,d0
  406.         moveq    #4,d1
  407.         jsr    MakeHex
  408.         
  409.         AddText    ASCII_Str,ASCII_StrSize
  410.         AddText    BPLCON3Value,BPLCON3ValueSize
  411.         AddText    CommaStr,CommaStrLength
  412.         swap    d5
  413.         lea    (BPLCON3Value,PC),a0
  414.         move.w    d5,d0
  415.         moveq    #4,d1
  416.         jsr    MakeHex
  417.         AddText    BPLCON3Value,BPLCON3ValueSize
  418.         
  419.         move.w    d5,d6            Multiply by three
  420.         add.w    d6,d6            Multiply by three
  421.         add.w    d5,d6            Multiply by three
  422.         subq.w    #1,d6
  423. Make32bit
  424.         moveq    #dctype_Long,d0
  425.         jsr    AddStartLine
  426.         
  427.         cmp.w    (_NumberOfItems2),d6
  428.         blt.s    CorrectItems32bit
  429.         move.w    (_NumberOfItems2),d5
  430.         subq.w    #1,d5
  431.         bra.s    RightItems32bit
  432. CorrectItems32bit
  433.         move.w    d6,d5
  434. RightItems32bit
  435.         sub.w    d5,d6
  436. Make32bit.2        
  437.         move.l    (a2)+,d0
  438.         moveq    #6,d1
  439.         lea    (ColourValue24,PC),a0
  440.         jsr    MakeHex
  441.         
  442.         AddText    ASCII_Str,ASCII_StrSize
  443.         AddText    ColourValue24,ColourValue24Size
  444.         tst.w    d5
  445.         beq.s    bit32SkipComma
  446.         AddText    Comma,CommaLength
  447. bit32SkipComma
  448.         
  449.         dbf    d5,Make32bit.2
  450.         
  451.         dbf    d6,Make32bit
  452.         
  453.         jsr    FlushBuffer
  454.         
  455.         movem.l    (SP)+,d2-3/d6-7/a5-6    Restore affected non scratch registers
  456.         rts
  457.  
  458.  
  459. _SaveCopper4bit
  460.         movem.l    d2-3/d6-7/a5-6,-(SP)    Store affected non scratch registers
  461.  
  462.         AddText    bit4Header,bit4HeaderSize
  463.         
  464.         jsr    FlushBuffer
  465.         
  466.         movem.l    (SP)+,d2-3/d6-7/a5-6    Restore affected non scratch registers
  467.         rts
  468.  
  469.  
  470. *------------------------------------------------------------------------
  471. *
  472. *     AddColourBank
  473. *
  474. *------------------------------------------------------------------------
  475. AddColourBank
  476.         bsr    AddStartLine
  477.         AddText    ColourBank,ColourBankSize
  478.         move.w    (_PicDepth,a4),d0
  479.         subq.w    #1,d0
  480.         sub.w    d6,d0
  481.         ror.w    #3,d0
  482.         or.w    (BPLCON3Extra,PC),d0    Add Extra bits to BPLCON3
  483.         moveq    #BPLCON3ValueSize,d1
  484.         lea    (BPLCON3Value,PC),a0
  485.         jsr    MakeHex
  486.         
  487.         AddText    BPLCON3Value,BPLCON3ValueSize
  488.         AddText    ASCII_Or,ASCII_OrSize
  489.         AddText    ASCII_OrMask,ASCII_OrMaskSize
  490.         
  491.         rts
  492.  
  493.  
  494. *------------------------------------------------------------------------
  495. *
  496. *     AddStartLine( SaveBuffer, DC_Type )
  497. *                   A3          D0
  498. *
  499. *  Adds the beginning of a line to a save buffer. The beginning of a
  500. *  line look like this: <TAB1>dc.w<TAB2>
  501. *
  502. *  pre:  _TAB1 - Number of tabs at the beginning of a line.
  503. *        _TAB2 - Number of tabs after the 'dc.w' statement.
  504. *        D0 - Type of dc statement. Accepted types are: dctype_long
  505. *                                                       dctype_word
  506. *        A3 - Pointer to a savebuffer structure.
  507. *  post: None.
  508. *
  509. *     Uneffected registers:
  510. *
  511. *------------------------------------------------------------------------
  512. AddStartLine
  513.         movem.l    d6/d0,-(SP)
  514.         
  515.         AddText    ASCII_LF,LFSize
  516.         move.w    (_TAB1),d6
  517.         jsr    AddTabs
  518.         move.l    (SP)+,d0
  519.         cmp.w    #dctype_Long,d0
  520.         beq.s    Make_dc_Long
  521.         AddText    Line_dcw,Line_dcw_Length
  522.         bra.s    AddSecondTAB
  523. Make_dc_Long
  524.         AddText    Line_dcl,Line_dcl_Length
  525. AddSecondTAB
  526.         move.w    (_TAB2),d6
  527.         jsr    AddTabs
  528.         
  529.         move.l    (SP)+,d6
  530.         rts
  531.         
  532. *------------------------------------------------------------------------
  533. *
  534. *     AddTabs( Tabs, SaveBuffer )
  535. *              D6    A3
  536. *
  537. *  Adds a series of tabs to SaveBuffer.
  538. *
  539. *  pre:  D6 - Number of tabs to add.
  540. *        A3 - Pointer to a buffer structure.
  541. *  post: None.
  542. *
  543. *------------------------------------------------------------------------
  544. AddTabs
  545.         subq.w    #1,d6
  546. WriteTabs
  547.         AddText    ASCII_TAB,TABSize
  548.         dbf    d6,WriteTabs
  549.         
  550.         rts
  551. **
  552. **  Variables.
  553. **        
  554.         SECTION    __MERGED,data
  555.         XDEF    _TAB1
  556.         XDEF    _TAB2
  557.         XDEF    _NumberOfItems1
  558.         XDEF    _NumberOfItems2
  559.         XDEF    _BPLCON3OrMask
  560.         
  561. _TAB1        dc.w    2        Default Value.
  562. _TAB2        dc.w    1        Same here.
  563. _NumberOfItems1    dc.w    4        Same here.
  564. _NumberOfItems2    dc.w    9        Same here.
  565. _BPLCON3OrMask    dc.l    BPLCON3OrMask
  566.  
  567.         SECTION    SaveFont8,code
  568. _SaveFont8
  569.         move.l    a4,-(SP)        Save SAS C Stack pointer.
  570.         
  571.         move.l    (SP)+,a4        Restore SAS C Stack pointer.
  572.         rts
  573.  
  574.  
  575. *------------------------------------------------------------------------
  576. *
  577. *  WriteBuffer( Buffer, Data, DataSize)
  578. *               A3      A5    D7
  579. *
  580. *     Writes 'Data' to a buffer. When buffer is full, the buffer will
  581. *     be flushed and the remaining data will be written to the buffer.
  582. *
  583. *  pre:  A3 - Pointer to a Buffer structure.
  584. *        A4 - SAS C Stack Pointer
  585. *        A5 - Pointer to the data to be written to 'Buffer'
  586. *        D7 - Size of the 'Data' buffer.
  587. *  post: None
  588. *
  589. *  Uneffected registers: A1-4, D4-6
  590. *
  591. *------------------------------------------------------------------------
  592.  
  593.         SECTION    WriteBuffer,code
  594. WriteBuffer
  595.         tst.l    d7
  596.         beq.s    DataEmpty
  597.         
  598.         move.l    (BufferLeft,a3),d1
  599.         cmp.l    d1,d7
  600.         bge.s    BufferOverflow
  601.         move.l    d7,d2
  602.         sub.l    d7,(BufferLeft,a3)
  603.         bra.s    CopyDataBuffer
  604. BufferOverflow
  605.         move.l    d1,d2
  606.         clr.l    (BufferLeft,a3)
  607. CopyDataBuffer
  608.         sub.l    d2,d7
  609.         move.l    (BufferSize,a3),d0
  610.         sub.l    d1,d0
  611.         move.l    (Buffer,a3),a0
  612.         add.l    d0,a0
  613. CopyDataBuffer.1
  614.         move.b    (a5)+,(a0)+
  615.         subq.l    #1,d2
  616.         bne.s    CopyDataBuffer.1
  617.         
  618.         tst.l    (BufferLeft,a3)
  619.         bne.s    WriteBuffer
  620.         
  621.         bsr.s    FlushBuffer
  622.         bra.s    WriteBuffer
  623. DataEmpty
  624.         rts
  625.  
  626. *------------------------------------------------------------------------
  627. *
  628. *  FlushBuffer( Buffer )
  629. *               A3
  630. *
  631. *     Flush the buffer. If buffer is empty, no flushing will occour.
  632. *
  633. *  pre:  A3 - Pointer to a buffer to be flushed
  634. *        A4 - SAS C Stack Pointer
  635. *  post: None.
  636. *
  637. *------------------------------------------------------------------------
  638.  
  639. FlushBuffer
  640.         move.l    (BufferSize,a3),d3
  641.         sub.l    (BufferLeft,a3),d3
  642.         beq.s    NothingInBuffer
  643.         
  644.         move.l    (FileHeader,a3),d1
  645.         move.l    (Buffer,a3),d2
  646.         move.l    (_DOSBase,a4),a6
  647.         jsr    (_LVOWrite,a6)
  648.         move.l    (BufferSize,a3),(BufferLeft,a3)
  649. NothingInBuffer
  650.         rts
  651.  
  652. *------------------------------------------------------------------------
  653. *
  654. *   MakeDecimal( Inter, Length, Buffer )
  655. *                D0.W   D1.W    A0.L
  656. *
  657. *     Converters an integer to a decimal representation in ASCII,
  658. *     leading zeroes are *not* removed
  659. *
  660. *  pre:  A0 - Pointer into which the converted integer will be stored.
  661. *        D0 - Integer to convert. Upper 16 bits are expected to be zero.
  662. *        D1 - Number of digits to be used.
  663. *  post: None.
  664. *
  665. *------------------------------------------------------------------------
  666.  
  667. MakeDecimal
  668.         subq.w    #1,d1
  669. Convert_dec
  670.         divu.w    #10,d0
  671.         swap    d0
  672.         add.b    #'0',d0
  673.         move.b    d0,(a0,d1)
  674.         clr.w    d0
  675.         swap    d0
  676.         dbf    d1,Convert_dec
  677.         
  678.         rts
  679.         
  680.  
  681. *------------------------------------------------------------------------
  682. *
  683. *   MakeHex( Inter, Length, Buffer )
  684. *            D0.L   D1.W    A0.L
  685. *
  686. *     Converters an integer to a hexadecimal representation in ASCII,
  687. *     leading zeroes are *not* removed
  688. *
  689. *  pre:  A0 - Pointer into which the converted integer will be stored.
  690. *        D0 - Integer to convert. Upper 16 bits are expected to be zero.
  691. *        D1 - Number of digits to be used.
  692. *  post: None.
  693. *
  694. *------------------------------------------------------------------------
  695.  
  696. MakeHex
  697.         subq.w    #1,d1
  698. Convert_hex
  699.         moveq    #0,d2
  700.         divu.l    #16,d2:d0
  701.         cmp.w    #10,d2
  702.         blt.s    NoAdjustment
  703.         addq.w    #7,d2
  704. NoAdjustment
  705.         add.b    #'0',d2
  706.         move.b    d2,(a0,d1)
  707.         dbf    d1,Convert_hex
  708.         
  709.         rts
  710.